;;; doom-stylix-theme.el --- stylix template created from doom-one -*- lexical-binding: t; no-byte-compile: t; -*-
;;
;; Author: Emmet K <https://gitlab.com/librephoenix>
;; Maintainer: Emmet K <https://gitlab.com/librephoenix>
;; Source: https://github.com/doomemacs/themes
;;
;;; Commentary:
;;
;; Stylix template for Doom Emacs.
;;
;;; Code:

(require 'doom-themes)

;;
;;; Variables

(defgroup doom-stylix-theme nil
  "Options for the `doom-one' theme."
  :group 'doom-themes)

(defcustom doom-stylix-brighter-modeline nil
  "If non-nil, more vivid colors will be used to style the mode-line."
  :group 'doom-stylix-theme
  :type 'boolean)

(defcustom doom-stylix-brighter-comments nil
  "If non-nil, comments will be highlighted in more vivid colors."
  :group 'doom-stylix-theme
  :type 'boolean)

(defcustom doom-stylix-padded-modeline doom-themes-padded-modeline
  "If non-nil, adds a 4px padding to the mode-line.
Can be an integer to determine the exact padding."
  :group 'doom-stylix-theme
  :type '(choice integer boolean))


;;
;;; Theme definition

(def-doom-theme doom-stylix
  "A theme generated from current stylix theme."

  ;; name        default   256           16
  ((bg         '("#{{base00-hex}}" "black"       "black"  ))
   (fg         '("#{{base05-hex}}" "#bfbfbf"     "brightwhite"  ))

   ;; These are off-color variants of bg/fg, used primarily for `solaire-mode',
   ;; but can also be useful as a basis for subtle highlights (e.g. for hl-line
   ;; or region), especially when paired with the `doom-darken', `doom-lighten',
   ;; and `doom-blend' helper functions.
   (bg-alt     '("#{{base01-hex}}" "black"       "black"        ))
   (fg-alt     '("#{{base07-hex}}" "#2d2d2d"     "white"        ))

   ;; These should represent a spectrum from bg to fg, where base0 is a starker
   ;; bg and base8 is a starker fg. For example, if bg is light grey and fg is
   ;; dark grey, base0 should be white and base8 should be black.
   (base0      '("#{{base00-hex}}" "black"       "black"        ))
   (base1      '("#{{base01-hex}}" "#1e1e1e"     "brightblack"  ))
   (base2      '("#{{base01-hex}}" "#2e2e2e"     "brightblack"  ))
   (base3      '("#{{base02-hex}}" "#262626"     "brightblack"  ))
   (base4      '("#{{base03-hex}}" "#3f3f3f"     "brightblack"  ))
   (base5      '("#{{base04-hex}}" "#525252"     "brightblack"  ))
   (base6      '("#{{base05-hex}}" "#6b6b6b"     "brightblack"  ))
   (base7      '("#{{base06-hex}}" "#979797"     "brightblack"  ))
   (base8      '("#{{base07-hex}}" "#dfdfdf"     "white"        ))

   (grey       base4)
   (red        '("#{{base08-hex}}" "#ff6655" "red"          ))
   (orange     '("#{{base09-hex}}" "#dd8844" "brightred"    ))
   (green      '("#{{base0B-hex}}" "#99bb66" "green"        ))
   (teal       '("#{{base0C-hex}}" "#44b9b1" "brightgreen"  ))
   (yellow     '("#{{base0A-hex}}" "#ECBE7B" "yellow"       ))
   (blue       '("#{{base0E-hex}}" "#51afef" "brightblue"   ))
   (dark-blue  '("#{{base0E-hex}}" "#2257A0" "blue"         ))
   (magenta    '("#{{base0F-hex}}" "#c678dd" "brightmagenta"))
   (violet     '("#{{base0F-hex}}" "#a9a1e1" "magenta"      ))
   (cyan       '("#{{base0D-hex}}" "#46D9FF" "brightcyan"   ))
   (dark-cyan  '("#{{base0C-hex}}" "#5699AF" "cyan"         ))

   ;; These are the "universal syntax classes" that doom-themes establishes.
   ;; These *must* be included in every doom themes, or your theme will throw an
   ;; error, as they are used in the base theme defined in doom-themes-base.
   (highlight      blue)
   (vertical-bar   (doom-darken base1 0.1))
   (selection      dark-blue)
   (builtin        magenta)
   (comments       (if doom-stylix-brighter-comments dark-cyan base5))
   (doc-comments   (doom-lighten (if doom-stylix-brighter-comments dark-cyan base5) 0.25))
   (constants      violet)
   (functions      magenta)
   (keywords       blue)
   (methods        cyan)
   (operators      blue)
   (type           yellow)
   (strings        green)
   (variables      (doom-lighten magenta 0.4))
   (numbers        orange)
   (region         `(,(doom-lighten (car bg-alt) 0.15) ,@(doom-lighten (cdr base1) 0.35)))
   (error          red)
   (warning        yellow)
   (success        green)
   (vc-modified    orange)
   (vc-added       green)
   (vc-deleted     red)

   ;; These are extra color variables used only in this theme; i.e. they aren't
   ;; mandatory for derived themes.
   (modeline-fg              fg)
   (modeline-fg-alt          base5)
   (modeline-bg              (if doom-stylix-brighter-modeline
                                 (doom-darken blue 0.45)
                               (doom-darken bg-alt 0.1)))
   (modeline-bg-alt          (if doom-stylix-brighter-modeline
                                 (doom-darken blue 0.475)
                               `(,(doom-darken (car bg-alt) 0.15) ,@(cdr bg))))
   (modeline-bg-inactive     `(,(car bg-alt) ,@(cdr base1)))
   (modeline-bg-inactive-alt `(,(doom-darken (car bg-alt) 0.1) ,@(cdr bg)))

   (-modeline-pad
    (when doom-stylix-padded-modeline
      (if (integerp doom-stylix-padded-modeline) doom-stylix-padded-modeline 4))))


  ;;;; Base theme face overrides
  (((line-number &override) :foreground base4)
   ((line-number-current-line &override) :foreground fg)
   ((font-lock-comment-face &override)
    :background (if doom-stylix-brighter-comments (doom-lighten bg 0.05)))
   (mode-line
    :background modeline-bg :foreground modeline-fg
    :box (if -modeline-pad `(:line-width ,-modeline-pad :color ,modeline-bg)))
   (mode-line-inactive
    :background modeline-bg-inactive :foreground modeline-fg-alt
    :box (if -modeline-pad `(:line-width ,-modeline-pad :color ,modeline-bg-inactive)))
   (mode-line-emphasis :foreground (if doom-stylix-brighter-modeline base8 highlight))

   ;;;; css-mode <built-in> / scss-mode
   (css-proprietary-property :foreground orange)
   (css-property             :foreground green)
   (css-selector             :foreground blue)
   ;;;; doom-modeline
   (doom-modeline-bar :background (if doom-stylix-brighter-modeline modeline-bg highlight))
   (doom-modeline-buffer-file :inherit 'mode-line-buffer-id :weight 'bold)
   (doom-modeline-buffer-path :inherit 'mode-line-emphasis :weight 'bold)
   (doom-modeline-buffer-project-root :foreground green :weight 'bold)
   ;;;; elscreen
   (elscreen-tab-other-screen-face :background "#{{base01-hex}}" :foreground "#{{base06-hex}}")
   ;;;; ivy
   (ivy-current-match :background dark-blue :distant-foreground base0 :weight 'normal)
   ;;;; LaTeX-mode
   (font-latex-math-face :foreground green)
   ;;;; markdown-mode
   (markdown-markup-face :foreground base5)
   (markdown-header-face :inherit 'bold :foreground red)
   ((markdown-code-face &override) :background (doom-lighten base3 0.05))
   ;;;; org-mode
   (org-block                        :background (doom-darken bg 0.05 ) :extend t)
   (org-code                         :background (doom-darken bg 0.05 ) :extend t)
   ;;;; rjsx-mode
   (rjsx-tag :foreground red)
   (rjsx-attr :foreground orange)
   ;;;; solaire-mode
   (solaire-mode-line-face
    :inherit 'mode-line
    :background modeline-bg-alt
    :box (if -modeline-pad `(:line-width ,-modeline-pad :color ,modeline-bg-alt)))
   (solaire-mode-line-inactive-face
    :inherit 'mode-line-inactive
    :background modeline-bg-inactive-alt
    :box (if -modeline-pad `(:line-width ,-modeline-pad :color ,modeline-bg-inactive-alt))))

  ;;;; Base theme variable overrides-
  ())

;;; doom-stylix-theme.el ends here